✒️ABAP Las Interfaces
ABAP Las Interfaces
Lección 5: Interfaces
1| Introducción a Interfaces
Las clases, sus instancias (los objetos) y el acceso a los objetos usando variables referenciadas son la base de la programación orientada a objetos en ABAP. Además, hay veces en las que es necesario para clases similares proporcionar funcionalidades similares pero que están codificadas diferentes en cada clase, las cuales dan un punto de contacto común con el usuario.
Ejemplo:
Podríamos tener dos clases similares, cuenta corriente y ahorro, las cuales tienen un método para calcular las comisiones del año, las interfaces y nombres de los métodos son los mismos pero la implementación es diferente. El usuario de las clases y las instancias tiene que ser capaces de ejecutar el método para todas las cuentas sin preocuparse del tipo de cada cuenta individual.
Con los objetos ABAP esto es posible mediante el uso de las interfaces.
2| Que son las Interfaces?
Son estructuras independientes que se pueden implementar en una clase para extender el ámbito de esa clase.
El ámbito específico de una clase viene definido por sus componentes y sus secciones de visibilidad. Por ejemplo, los componentes públicos de una clase definen su ámbito público, ya que todos sus atributos y los parámetros de los métodos pueden ser utilizados por todos los usuarios. Los componentes protegidos de una clase definen su ámbito en lo que se refiere a sus subclases. Las interfaces extienden el ámbito de una clase añadiendo sus propios componentes a la sección pública. Esto permite a los usuarios acceder a diferentes clases por medio de un punto de contacto común. Las interfaces junto con la herencia proporcionan uno de los pilares básicos del polimorfismo, ya que permiten que un sólo método con una interface se comporte distinto en diferentes clases.
Las interfaces permiten usar diferentes clases de una manera uniforme, aprovechando las referencias a la interfaces es decir el polimorfismo. Por ejemplo las interfaces implementadas en diferentes clases amplían el ámbito público de la clase en el mismo conjunto de componentes, si la clase no tiene ningún componente publico especifico de ella misma entonces la interface describe completamente el ámbito púbico de la clase.
3| Definición de una Interface
Las interfaces se pueden definir globalmente en el repositorio R/3 o localmente en un programa Abap. la definición de una interface local es el código existente entre las sentencias:
INTERFACE <interface>
….
ENDINTERFACE.
La definición contiene la declaración de todos los componentes (atributos, métodos y eventos) de la interface. Se pueden definir los mismos componentes en una interface que en una clase. Los componentes de las interfaces no tienen que ser asignados a ninguna sección de visibilidad ya que automáticamente pertenecen a la sección publica de la clase en la que la interface es implementada.
Las interfaces no tienen una parte de implementación ya que sus métodos son implementados en la clase que implementa la interface.
4| Implementación de Interfaces
Cuando se implementa una interface en una clase, los componentes de la interface se añaden al resto de componentes de la sección pública. Un componente de una interface puede ser direccionado como si fuese un miembro de la clase bajo el nombre:
<interface~componente>.
La clase tiene que implementar los métodos de todas las interfaces implementadas en ella. La parte de implementación de la case debe contener la implementación de cada método de la interface:
METHOD <interface~metodo>.
….
ENDMETHOD.
Las interfaces pueden ser implementadas por diferentes clases. Cada una de las clases es ampliada con el mismo conjunto de componentes, aunque los métodos de la interface pueden ser implementados de manera distinta en cada clase.
5| Referencias a Interfaces
Las variables referenciadas permiten acceder a los objetos. En lugar de crear variables referenciadas con referencia a una clase, se pueden crear con referencia a una interface. Este tipo de variables referenciadas puede contener referencias a los objetos de las clases que implementen esa interface. Para definir una referencia a una interface se usa la siguiente adición:
TYPE REF TO <interface>
La interface que utilicemos para definir la referencia debe haber sido declarada en el programa antes que esta declaración tenga lugar.
Una variable referenciada con el tipo de referenciado a una interface se llama variable referenciada a una interface, o referencia a interface simplemente. Una referencia a interface permite al usuario usar la siguiente declaración:
<ireferencia>-><componente>
Para acceder a todos los componentes visibles de la interface del objeto al cual la referencia está apuntando. Este permite al usuario acceder a todos los componentes del objeto que fueron añadidos a su definición al implementar la interface.
6| Direccionar y asignar objetos usando referencias a interfaces
Para crear un objeto de la clase primero se tiene que haber declarado una variable referenciada con referencia a la clase. Si la clase implementa una interface, se puede usar la siguiente asignación entre la variable referenciada a la clase y una referencia a interface, para hacer que la referencia a interface apunte al mismo objeto que la referencia a clase en:
<ireferencia>=<creferencia>
Si la interface contiene un atributo dependiente de instancia y un método dependiente de instancia se puede direccionar los componentes de la interface como describimos a continuación. Usando la variable referenciada a una clase:
> Para acceder a un atributo utilizaremos lo siguiente:
<creferencia>-><interface~atributo>
> Para acceder al método utilizaremos:
CALL METHOD <creferencia>-><interface~metodo>
Usando la variable referenciada a una interface:
> Para acceder a un atributo utilizaremos:
<ireferencia>-><atributo>
> Para acceder al método utilizaremos:
CALL METHOD <ireferencia>-><metodo>
Siempre que los componentes estáticos de las interfaces estés implicados, solo se puede usar el nombre de la interface para acceder a las constantes:
> Para acceder a una constante utilizaremos los siguiente:
<interface>=><constante>
Para todo los demás componentes estáticos de una interface, solo se pueden usar referencias a objetos o la clase que implementa la interface:
> Para acceder a un atributo estático utilizaremos:
<clase>=><interface~atributo>
> Para llamar a un método estático utilizaremos:
CALL METHOD <class>=><intf~meth>
7| Ejemplo de Interfaces
A continuación veremos un Ejemplo de una programa ABAP que utiliza interfaces. Aquí declaramos la interface ESTADO y las clases CONTADOR y BICICLETA. Dentro de la sección pública de ambas clases declaramos la interface ESTADO.
INTERFACE estado.
METHODS imprimir.
ENDINTERFACE.
CLASS contador DEFINITION.
PUBLIC SECTION.
INTERFACES estado.
METHODS incrementar.
PRIVATE SECTION.
DATA cuenta TYPE i.
ENDCLASS.
CLASS contador IMPLEMENTATION.
METHOD estado~imprimir.
WRITE: / 'La cuenta en el contador es: ', cuenta.
ENDMETHOD.
METHOD incrementar.
ADD 1 TO cuenta.
ENDMETHOD.
ENDCLASS.
CLASS bicicleta DEFINITION.
PUBLIC SECTION.
INTERFACES estado.
METHODS manejar.
PRIVATE SECTION.
DATA velocidad TYPE i.
ENDCLASS.
CLASS bicicleta IMPLEMENTATION.
METHOD estado~imprimir.
WRITE: / 'La velocidad de la bicicleta es: ', velocidad.
ENDMETHOD.
METHOD manejar.
ADD 10 TO velocidad.
ENDMETHOD.
ENDCLASS.
Luego dentro del evento START-OF-SELCTION creamos los objetos CUENTA y BICI. Ejecutamos los métodos CUENTA->INCREMENTAR y BICI->MANEJAR, almacenamos los resultados en la tabla TI_ESTADO y recorremos la tabla llamando al método IMPRIMIR.
DATA: cuenta TYPE REF TO contador,
bici TYPE REF TO bicicleta,
estado TYPE REF TO estado,
ti_estado TYPE TABLE OF REF TO estado.
START-OF-SELECTION.
CREATE OBJECT: cuenta, bici.
DO 5 TIMES.
CALL METHOD: cuenta->incrementar,
bici->manejar.
ENDDO.
APPEND: cuenta TO ti_estado,
bici TO ti_estado.
LOOP AT ti_estado INTO estado.
CALL METHOD estado->imprimir.
ENDLOOP.
La salida por pantalla del programa será:
Interfaces en ABAP
-----------------------------------------------------------
La cuenta es el contador es: 5
La velocidad de la bicicleta es: 50
Las interfaces son tipos de objeto que se pueden definir localmente o globalmente en un programa ABAP a través del repositorio R/3, en la tx SE24, tal como veremos mas adelante en detalle para las clases, si se definen interfaces globalmente entonces estas son almacenadas en un tipo especial del programa ABAP llamado INTERFACE POOL el cual es de tipo J y sirve como contenedor del respectivo tipo de objeto, cada pool de interface contiene la definición de una sola interface, este programa es generado automáticamente cuando creamos la interface global. Un pool de interfaces es comparable a un modo pool o a un grupo de funciones, los pool de interfaces no contienen ninguna sentencia ejecutable, cuando se implementa una interface en una clase, la definición de la interface queda implícitamente incluida en la definición de la clase.
 
 
 
Sobre el autor
Publicación académica de Hernan Cabezas, en su ámbito de estudios para la Carrera Consultor ABAP.
Hernan Cabezas
Peru - Legajo: ZM88T
✒️Autor de: 117 Publicaciones Académicas
🎓Egresado de los módulos:
Certificación Académica de Hernan Cabezas