✒️ABAP Los Eventos

1 | Las clase global

Una clase global es visible y puede ser usada en cualquier programa.

Sólo pueden ser creadas usando la herramienta de creación de clases en el ABAP Workbench, transacción SE24.

Cuando se define una clase en forma global a través del repositorio correspondiente a la transacción SE24,

se genera un programa ABAP especial llamado "Pool de clases", el cual es del tipo "K".

El "Pool de clases" tiene una parte de definiciones y otra parte de implementaciones de la clase.

Este programa tiene muchas diferencias con respecto a un programa ABAP común y silvestre.

Las principales diferencias son las siguientes:

Los programas ABAP tales como los reportes, los module pools o los módulos de funciones,

usualmente tienen una parte de declaración en donde se definen los datos globales.

Estos datos son visibles en todos los bloques de procesamiento del programa.

Los únicos bloques de procesamiento que se pueden utilizar en un "Pool de clases" son la parte de declaración e implementación de la clase global.

La parte de implementación solo podría implementar los métodos declarados en la clase global.

Los bloques de procesamiento del "Pool de clases" no son controlados por el entorno de ejecución ABAP.

No ocurren eventos, y no se puede llamar a cualquiera de los módulos o procedimientos de diálogo.

Debido a que los eventos y módulos de dialogo no están permitidos en las clases, entonces no se pueden procesar las pantallas en las clases.

2. los pasos para crear una clase global son:

Se ingresa a la transacción SE24, y en object type introducimos el nombre de la clase que sera z_cl_vehiculo, y presionamos el botón crear.

Luego seleccionamos Class y continuamos.

En la siguiente ventana ingresamos la descripción de la clase,

si presionamos el botón a la derecha de la clase podemos definir una opción de herencia especificando el nombre de la superclase,

en INSTANTIANTION podemos definir la visibilidad de la clase que pude ser publica, privada o protegida. por ultimo guardamos.

Vamos a definir los atributos de la clase, definimos SPEED que será un atributo de instancia,

definimos la visibilidad del atributo como publica, y el tipo será I y definimos una denominación para el mismo.

También definimos los atributos MAX_SPEED, STOP y WRITE.

Ahora definimos los métodos, creamos el método INCREASE_SPEEP

en cual creamos como método de instancia y lo definimos con visibilidad publica y la descripción Aumento de la velocidad.

También creamos el método CALCULATE_STOP el cual tendrá el objetivo de reiniciar la velocidad

y el método DISPLAY_WRITE que mostrara el listado de velocidades.

Para este método definimos parámetros, P_PARAMETRO tipo IMPORTING, tipo P, con la descripción parametro.

también creamos el parámetro P_RESULTADO de entrada, tipo p, con la descripción resultado.

Ahora creamos una excepción, con el método DISPLY_WRITE.

creamos la excepción VEHICULO_NO_EXISTE con la descripción "El vehículo no existe"

también creamos el evento cambio estado vehículo como de instancia, con visibilidad publica y la descripción acorde a su propósito.

Por ultimo podemos crear los tipos para utilizar dentro de nuestra clase global.

Finalmente grabamos y activamos la clase.

1 | Disparar y manejar eventos

En objetos ABAP hay ciertos métodos que se conocen como disparadores (triggers) y otros que se conocen como manejadores (handlers).

Los triggers son los métodos que disparan un evento, mientras que los handlers son los métodos que se ejecutan cuando ocurre un evento.

Para disparar un evento una clase tiene que:

Declarar el evento en la parte declarativa.

Disparar el evento en uno de sus métodos.

Los eventos se declaran en la parte declarativa de una clase o en una interface.

Para declarar eventos dependientes de instancia se usa la siguiente sentencia:

EVENTS <evento> EXPORTING value(<variable>) TYPE [OPCIONAL].

Imagen 1.1 - Sintaxis utilizada para la declaración de eventos dependientes de instancia

Para declarar eventos estáticos se usa la siguiente sentencia:

CLASS-EVENTS <evento> …

Imagen 1.2 - Sintaxis utilizada para la declaración de eventos estáticos

Cuando se declara un evento se puede usar la adición EXPORTING para especificar parámetros que se pasan al manejador del evento.

Los parámetros se pasan siempre por valor.

Los eventos dependientes de instancia siempre contienen el parámetro implícito SENDER,

el cual tiene el tipo de una referencia al tipo o a la interface en la cual el evento es declarado.

Un evento dependiente de instancia en una clase puede ser disparado por cualquier método en la clase.

Los eventos estáticos son disparados por métodos estáticos.

Para disparar un evento en un método se usa la siguiente sentencia:

RAISE EVENT <evento> EXPORTING <variable> = <variable_i>.

Imagen 1.3 - Sintaxis utilizada para disparar un evento en un método

Por cada parámetro formal que no esté definido como opcional se tiene que pasar el correspondiente parámetro real en la adición EXPORTING.

La referencia a sí mismo ME es pasada automáticamente al parámetro implícito SENDER.

2 | Los eventos manejadores

Los eventos se usan para ejecutar una serie de métodos. Estos métodos tienen que:

Estar definidos como eventos manejadores (handler) de ese evento.

Estar registrados en tiempo de ejecución para el evento.

Una clase puede contener métodos manejadores de eventos para eventos tanto de su propia clase como de otras clases.

Para declarar un método manejador de eventos dependiente de instancia se usa la siguiente sentencia:

METHODS <metodo> FOR EVENT <evento> OF <variable>

Imagen 2.1 - Sintaxis utilizada para declarar un método manejador de eventos dependiente de instancia

Para métodos estáticos se usa la misma sentencia con CLASS-METHODS en vez de METHODS.

La interface de un método manejador de eventos sólo puede contener parámetros formales definidos en la declaración del evento.

Los atributos de los parámetros también son adoptados por el evento.

El método manejador de eventos no tiene por que usar todos los parámetros pasados en la sentencia RAISE EVENT.

3 | El registro de métodos manejadores de eventos

Para permitir a un método manejador de eventos reaccionar a un evento,

se tiene que determinar en tiempo de ejecución el disparador al cual va a reaccionar.

Esto se hace con la siguiente sentencia:

SET HANDLER … <hi> … FOR ….

Imagen 3.1 - Sintaxis utilizada para determinar el disparador que reaccionará a un evento

Esta sentencia relaciona los métodos manejadores de eventos con sus correspondientes métodos.

Hay cuatro tipos diferentes de eventos:

Eventos dependientes de instancia declarados en una clase.

Eventos dependientes de instancia declarados en una interface.

Eventos estáticos declarados en una clase.

Eventos estáticos declarados en una interface.

La sintaxis y el efecto de la sentencia SET HANDLER depende de cual de los cuatro casos que detallamos tenga lugar.

Para un evento dependiente de instancia se tiene que usar la adición FOR para especificar la instancia para la cual se quiere registrar el manejador.

Se puede especificar una sola instancia como disparador usando una variable referenciada:

SET HANDLER … <hi> … FOR <ref>.

Imagen 3.2 - Sintaxis utilizada para determinar el disparador de eventos dependientes de instancia

O se puede registrar el manejador para todas las instancias que puedan disparar el evento:

SET HANDLER … <hi> … FOR ALL INSTANCES.

Imagen 3.3 - Registramos el manejador para todas las instancias

En este caso el registro se aplica incluso a las instancias que aún no han sido creadas cuando se registra el manejador.

No se puede usar la adición FOR para los eventos estáticos:

SET HANDLER … <hi> …

Imagen 3.4 - Sintaxis utilizada para eventos estáticos

El registro se aplica automáticamente a la clase entera o a todas las clases que implementan la interface que contiene el evento estático.

En el caso de las interfaces, el registro también se aplica a las clases que aún no han sido cargadas cuando el manejador se registra.

4 | La coordinación en el manejo de eventos

Después de la sentencia RAISE EVENT, todos los métodos manejadores registrados son ejecutados

antes de que la siguiente sentencia sea procesada (manejo de eventos sincrónico).

Si un método manejador de eventos desencadena eventos,

los correspondientes métodos manejadores de eventos son ejecutados antes de que el método manejador original continúe.

Para evitar la posibilidad de un bucle infinito, actualmente los eventos sólo se pueden anidar 64 niveles.

Los métodos manejadores de eventos son ejecutados en el orden en el que son registrados.

Debido a que los manejadores de eventos son registrados dinámicamente, no se puede saber el orden en el que serán procesados.

Por esto se deben programar todos los manejadores de eventos como si se fuesen a ejecutar todos simultáneamente.

5 | Ejemplo del manejo de eventos

El siguiente ejemplo muestra cómo se trabaja con eventos en los objetos ABAP. La clase CONTADOR implementa un contador.

Se desencadena el evento valor_critico cuando el valor UMBRAL es excedido y se visualiza la diferencia.

La clase MANEJADOR puede manejar las excepciones en la clase CONTADOR.

El manejador es registrado en tiempo de ejecución para todas las variables referenciadas que apunten al objeto.

CLASS contador DEFINITION.

PUBLIC SECTION.

METHODS incrementar_contador.

EVENTS valor_critico EXPORTING value(exceso) TYPE i.

PRIVATE SECTION.

DATA: cuenta TYPE i,

umbral TYPE i VALUE 10.

ENDCLASS. "contador DEFINITION

CLASS contador IMPLEMENTATION.

METHOD incrementar_contador.

DATA diferencia TYPE i.

ADD 1 TO cuenta.

IF cuenta > umbral.

diferencia = cuenta - umbral.

RAISE EVENT valor_critico EXPORTING exceso = diferencia.

ENDIF.

ENDMETHOD. "incrementar_contador

ENDCLASS. "contador IMPLEMENTATION

CLASS manejador DEFINITION.

PUBLIC SECTION.

METHODS manejar_exceso FOR EVENT valor_critico OF contador

IMPORTING exceso.

ENDCLASS. "manejador DEFINITION

CLASS manejador IMPLEMENTATION.

METHOD manejar_exceso.

WRITE: / 'El Exceso es: ', exceso.

ENDMETHOD. "manejar_exceso

ENDCLASS. "manejador IMPLEMENTATION

Imagen 5.1 - Definimos e implementamos las clases CONTADOR y MANEJADOR

Luego en el evento START-OF-SELECTION se declarará lo siguiente:

DATA: cuenta TYPE REF TO contador,

manejador TYPE REF TO manejador.

START-OF-SELECTION.

CREATE OBJECT: cuenta, manejador.

SET HANDLER manejador->manejar_exceso FOR ALL INSTANCES.

DO 20 TIMES.

CALL METHOD cuenta->incrementar_contador.

ENDDO.

Imagen 5.2 - Visualizamos la lógica implementada en el START-OF-SELECTION

Y la salida por pantalla del programa será la que vemos a continuación:

Imagen 5.3 - Salida por pantalla del programa